hk.pkl

// Хуки ставит `hk install`: на git 2.54+ это записи hook.* в .git/config,
// общий core.hooksPath дерева кита они не трогают.
amends "package://github.com/jdx/hk/releases/download/v2.8.1/hk@2.8.1#/Config.pkl"
import "package://github.com/jdx/hk/releases/download/v2.8.1/hk@2.8.1#/Builtins.pkl"

// Быстрые проверки идут на каждый коммит. Сеть и долгие шаги вынесены в all:
// их гоняют check, pre-push и CI.
local fast = new Mapping<String, Step> {
  ["ruff-format"] {
    glob = List("**/*.py")
    check = "uv run ruff format --check {{files}}"
    fix = "uv run ruff format {{files}}"
  }
  ["ruff"] {
    glob = List("**/*.py")
    check = "uv run ruff check {{files}}"
    fix = "uv run ruff check --fix {{files}}"
  }
  ["rumdl"] = Builtins.rumdl
  ["typos"] = Builtins.typos
  ["jactionlint"] = Builtins.jactionlint
}

local all = (fast) {
  ["ty"] {
    glob = List("**/*.py")
    check = "uv run ty check"
  }
  ["lychee"] {
    glob = List("**/*.md")
    check = "lychee --config lychee.toml --no-progress {{files}}"
  }
}

hooks {
  // stash выключен: на время хука он откатывает непроиндексированные файлы
  // рабочего дерева, в том числе чужие правки параллельной сессии.
  ["pre-commit"] {
    fix = true
    stash = "none"
    steps = fast
  }
  // История читается release-please, а коммиты идут прямо в main, поэтому
  // заголовок проверяется до записи. В CI тот же commitlint гоняется по
  // диапазону пуша.
  ["commit-msg"] {
    steps {
      ["commitlint"] {
        check = "commitlint --edit {{commit_msg_file}}"
      }
    }
  }
  ["pre-push"] {
    steps = all
  }
  ["check"] { steps = all }
  ["fix"] {
    fix = true
    steps = all
  }
}