build.gradle

buildscript {
    repositories {
        mavenCentral()
        google()
        maven {
            url = "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath libs.android.build.gradle
        classpath libs.spotbugs.gradle.plugin
    }
}

plugins {
    id 'io.github.gradle-nexus.publish-plugin' version '2.0.0'
    id 'org.jmonkeyengine.nativeimage' apply false
}

import org.gradle.api.file.RelativePath

// Set the license for IDEs that understand this
ext.license = file("$rootDir/source-file-header-template.txt")

apply plugin: 'base'
apply from: file('version.gradle')

group = 'org.jmonkeyengine'
version = jmeFullVersion

nexusPublishing {
    repositories {
        sonatype {
            nexusUrl.set(uri('https://ossrh-staging-api.central.sonatype.com/service/local/'))
            snapshotRepositoryUrl.set(uri('https://central.sonatype.com/repository/maven-snapshots/'))
            username = findProperty('sonatypeUsername') ?: findProperty('centralUsername') ?: 'Unknown user'
            password = findProperty('sonatypePassword') ?: findProperty('centralPassword') ?: 'Unknown password'
        }
    }
}

allprojects {
    repositories {
        mavenCentral()
        google()
    }
    tasks.withType(Jar) {
        duplicatesStrategy = 'include'
    }
}

// This is applied to all sub projects
subprojects {
    if(project.name.equals('jme3-android-examples') || project.name.equals('jme3-screenshot-tests-android')) {
        apply from: rootProject.file('common-android-app.gradle')
    } else {
        apply from: rootProject.file('common.gradle')
    }

    def isAndroidApp = project.plugins.hasPlugin('com.android.application')
    if (!project.name.endsWith("-native") && !isAndroidApp && enableSpotBugs != "false" ) {
        apply plugin: 'com.github.spotbugs'

        // Currently we only warn about issues and try to fix them as we go, but those aren't mission critical.
        spotbugs {
            ignoreFailures = true
            toolVersion = libs.versions.spotbugs.get()
        }

        tasks.withType(com.github.spotbugs.snom.SpotBugsTask ) {
            reports {
                html.required = !project.hasProperty("xml-reports")
                xml.required = project.hasProperty("xml-reports")
            }
        }
    }
}

def nativeImagePluginBuild = gradle.includedBuild('jme3-nativeimage-plugin')
def nativeImagePluginPublishTasks = [
        publish                                      : ':publish',
        publishToMavenLocal                         : ':publishToMavenLocal',
        install                                      : ':install',
        publishMavenPublicationToCentralRepository  : ':publishAllPublicationsToCentralRepository',
        publishMavenPublicationToSNAPSHOTRepository : ':publishAllPublicationsToSNAPSHOTRepository',
        publishMavenPublicationToDistRepository     : ':publishAllPublicationsToDistRepository',
        publishAllPublicationsToCentralRepository   : ':publishAllPublicationsToCentralRepository',
        publishAllPublicationsToSNAPSHOTRepository  : ':publishAllPublicationsToSNAPSHOTRepository',
        publishAllPublicationsToDistRepository      : ':publishAllPublicationsToDistRepository',
        publishToSonatype                           : ':publishToSonatype',
        closeSonatypeStagingRepository              : ':closeSonatypeStagingRepository',
        closeStagingRepositories                    : ':closeStagingRepositories'
]

subprojects {
    tasks.configureEach { task ->
        String includedTaskPath = nativeImagePluginPublishTasks[task.name]
        if (includedTaskPath != null) {
            task.dependsOn nativeImagePluginBuild.task(includedTaskPath)
        }
    }
}

gradle.projectsEvaluated {
    [
            publishToSonatype             : ':publishToSonatype',
            closeSonatypeStagingRepository: ':closeSonatypeStagingRepository',
            closeStagingRepositories      : ':closeStagingRepositories'
    ].each { rootTaskName, includedTaskPath ->
        def rootTask = tasks.findByName(rootTaskName)
        if (rootTask != null) {
            rootTask.dependsOn nativeImagePluginBuild.task(includedTaskPath)
        }
    }
}

tasks.register('run') {
    dependsOn ':jme3-examples:run'
    description = 'Run the jME3 examples'
}

tasks.register('runAndroidExamples') {
    description = 'Run the Android examples selector'
    def androidExamplesProject = findProject(':jme3-android-examples')
    if (androidExamplesProject != null) {
        dependsOn ':jme3-android-examples:runAndroidExamples'
    } else {
        doLast {
            throw new GradleException('Android examples are not available. Request an Android examples task and configure an Android SDK.')
        }
    }
}

tasks.register('runIosExamples') {
    description = 'Run the iOS examples selector'
    def iosExamplesProject = findProject(':jme3-ios-examples')
    if (iosExamplesProject != null) {
        dependsOn ':jme3-ios-examples:runIosExamples'
    } else {
        doLast {
            throw new GradleException('iOS examples are not available. Request an iOS examples task.')
        }
    }
}

defaultTasks 'run'

def libDist = tasks.register('libDist') {
    dependsOn(subprojects.collect { it.tasks.named('build') })
    description = 'Builds and copies the engine binaries, sources and javadoc to build/libDist'

    doLast {
        File libFolder = mkdir("$buildDir/libDist/lib")
        File sourceFolder = mkdir("$buildDir/libDist/sources")
        File javadocFolder = mkdir("$buildDir/libDist/javadoc")
        subprojects.each {project ->
            if(!project.hasProperty('mainClassName')){
                project.tasks.withType(Jar).each {archiveTask ->
                    String classifier = archiveTask.archiveClassifier.get()
                    String ext = archiveTask.archiveExtension.get()
                    File archiveFile = archiveTask.archiveFile.get().asFile
                    if (classifier == "sources") {
                        copy {
                            from archiveFile
                                into sourceFolder
                                rename {project.name + '-' + classifier + '.' + ext}
                        }
                    } else if (classifier == "javadoc") {
                        copy {
                            from archiveFile
                                into javadocFolder
                                rename {project.name + '-' + classifier + '.' + ext}
                        }
                    } else{
                        copy {
                            from archiveFile
                                into libFolder
                                rename {project.name + '.' + ext}
                        }
                    }
                }
            }
        }
    }
}

tasks.register('createZipDistribution', Zip) {
    dependsOn(tasks.named('dist'), libDist)
    description = 'Package the nightly zip distribution'
    archiveFileName = provider {
        "jME" + jmeFullVersion + ".zip"
    }
    into("/") {
         from {"./dist"}
    }
    into("/sources") {
        from {"$buildDir/libDist/sources"}
    }
}

tasks.register('copyLibs', Copy) {
//    description 'Copies the engine dependencies to build/libDist'
    from {
        subprojects*.configurations*.implementation*.copyRecursive({ !(it instanceof ProjectDependency); })*.resolve()
    }

    into "$buildDir/libDist/lib-ext" //buildDir.path + '/' + libsDirName + '/lib'
}

tasks.register('dist') {
    dependsOn ':jme3-examples:dist', tasks.named('mergedJavadoc')
    description = 'Creates a jME3 examples distribution with all jme3 binaries, sources, javadoc and external libraries under ./dist'
}

def mergedJavadocSubprojects = [
        ":jme3-android",
        ":jme3-core",
        ":jme3-desktop",
        ":jme3-effects",
        ":jme3-ios",
        ":jme3-jbullet",
        ":jme3-jogg",
        ":jme3-lwjgl",
        ":jme3-lwjgl3",
        ":jme3-networking",
        ":jme3-niftygui",
        ":jme3-plugins",
        ":jme3-terrain",
]
tasks.register('mergedJavadoc', Javadoc) {
    description = 'Creates Javadoc from all the projects.'
    title = 'jMonkeyEngine3'
    destinationDir = file("dist/javadoc")

    def javadocErrorsEnabled = findProperty('enableJavadocError') == 'true'
    failOnError = javadocErrorsEnabled
    options.encoding = 'UTF-8'
    if (javadocErrorsEnabled) {
        options.addBooleanOption('Werror', true)
        options.addBooleanOption('Xdoclint:all,-missing', true)
    } else {
        options.addStringOption('Xdoclint:none', '-quiet')
    }

    options.overview = file("javadoc-overview.html")
    source = mergedJavadocSubprojects.collect { project(it).sourceSets.main.allJava }
    classpath = files(mergedJavadocSubprojects.collect { project(it).sourceSets.main.compileClasspath })
}

def cleanMergedJavadoc = tasks.register('cleanMergedJavadoc', Delete) {
    delete file('dist/javadoc')
}

tasks.named('clean') {
    dependsOn cleanMergedJavadoc
}

apply from: 'gradle/jacoco.gradle'