feat: add smart factory CSML implementation

smartFactory/arm.pkl

@@ -0,0 +1,203 @@
+import
+  "https://raw.githubusercontent.com/CollaborativeStateMachines/Cirrina/refs/heads/develop/src/main/resources/pkl/csm/csml.pkl"
+
+import "events.pkl" as Events
+import "serviceTypes.pkl" as ServiceTypes
+import "variables.pkl" as Vars
+
+armFSM = new csml.StateMachine {
+  transient {
+    ["pickupSuccess"] = "true"
+    ["errorMsg"] = "''"
+    ["partsAssembled"] = "0"
+    ["partsPerProduct"] = "1000"
+  }
+
+  states {
+    ["idleState"] = new csml.Initial {
+      entry {
+        new csml.Match {
+          cases {
+            new csml.Case {
+              of = "!pickupSuccess"
+              yields {
+                new csml.Emit { event = new csml.Internal { topic = Events.ePickupNotSuccess } }
+              }
+            }
+          }
+        }
+      }
+
+      on {
+        [Events.eJobDone] {
+          to = "jobDoneState"
+        }
+        [Events.eArmPickup] {
+          to = "pickupState"
+          provided = "!\(Vars.vIsJobDone)"
+        }
+        [Events.ePickupNotSuccess] {
+          to = "pickupState"
+        }
+      }
+    }
+
+    ["pickupState"] {
+      entry {
+        new csml.Invoke {
+          type = ServiceTypes.stPickup
+        }
+      }
+
+      on {
+        [Events.eUpdatePickupStatus] {
+          yields {
+            new csml.Eval { expression = "pickupSuccess = $success" }
+            new csml.Match {
+              cases {
+                new csml.Case {
+                  of = "$success"
+                  yields {
+                    new csml.Emit {
+                      event { topic = Events.ePickedUp }
+                    }
+                  }
+                }
+              }
+              default = new csml.Eval { expression = "errorMsg = 'Pickup failed...'" }
+            }
+            new csml.Emit { event = new csml.Internal { topic = Events.eCheckPickUpSuccess } }
+          }
+        }
+
+        [Events.eCheckPickUpSuccess] {
+          to = "assembleState"
+          provided = "pickupSuccess"
+          or = "errorState"
+        }
+      }
+    }
+
+    ["errorState"] {
+      entry {
+        new csml.Emit {
+          event {
+            topic = Events.eProcessMessage
+            data { ["msg"] = "'Fatal robotic arm failure: ' + errorMsg" }
+          }
+          target = "'messageProcessor'"
+        }
+      }
+
+      after {
+        ["pickupRetryTimeout"] {
+          delay = "2000"
+          triggers = new csml.Emit { event = new csml.Internal { topic = Events.eRetry } }
+        }
+      }
+
+      on {
+        [Events.eRetry] {
+          to = "assembleState"
+          provided = "pickupSuccess"
+          or = "returnState"
+        }
+
+        [Events.eUpdatePickupStatus] {
+          yields {
+            new csml.Eval { expression = "pickupSuccess = $success" }
+          }
+        }
+
+        [Events.eJobDone] {
+          to = "jobDoneState"
+        }
+      }
+    }
+
+    ["assembleState"] {
+      entry {
+        new csml.Invoke {
+          type = ServiceTypes.stAssemble
+        }
+      }
+
+      on {
+        [Events.eCheckAssembleSuccess] {
+          yields {
+            new csml.Match {
+              cases {
+                new csml.Case {
+                  of = "$success"
+                  yields {
+                    new csml.Emit {
+                      event = new csml.Internal { topic = Events.eAssemblySuccessful }
+                    }
+                  }
+                }
+                new csml.Case {
+                  of = "!($success)"
+                  yields {
+                    new csml.Emit {
+                      event = new csml.Internal { topic = Events.eAssemblyUnsuccessful }
+                    }
+                  }
+                }
+              }
+            }
+          }
+        }
+
+        [Events.eAssemblySuccessful] {
+          to = "returnState"
+          yields {
+            new csml.Eval { expression = "partsAssembled = partsAssembled + 1" }
+            new csml.Emit {
+              event { topic = Events.eAssemblyComplete }
+              target = "'monitor'"
+            }
+          }
+        }
+
+        [Events.eAssemblyUnsuccessful] {
+          to = "errorState"
+          yields {
+            new csml.Eval { expression = "errorMsg = 'Assemble failed...'" }
+          }
+        }
+      }
+    }
+
+    ["returnState"] {
+      entry {
+        new csml.Invoke {
+          type = ServiceTypes.stReturnToStart
+        }
+      }
+
+      on {
+        [Events.eResetArm] {
+          to = "idleState"
+          yields {
+            new csml.Match {
+              cases {
+                new csml.Case {
+                  of = "partsAssembled >= partsPerProduct"
+                  yields {
+                    new csml.Eval { expression = "partsAssembled = 0" }
+                    new csml.Emit {
+                      event { topic = Events.eProductComplete }
+                      target = "'jobController'"
+                    }
+                  }
+                }
+              }
+            }
+          }
+        }
+      }
+    }
+
+    ["jobDoneState"] = new csml.Terminal {}
+  }
+}